[WoW] Using Click Castsequences

[Ualaa]

Using Click for Multiple Castsequences

Goal
We want to create a master macro, which can be spammed very quickly. Based on our spam speed, we want it to call our damage dealing spells in the order we specify, and to have them recast at the best possible time. We want all this to be accomplished from spamming a single button.



Basics
We will build two types of macros for "Click". The first is the master macro, which calls the others. The second are the "Castsequence" macros, which execute the spells we desire.

We can place our Castsequence Macro's on several bars. Within the default interface these are:

Default Bar....... /Click ActionButton#
Bottom Left......./Click MultiBarBottomLeftButton#
Bottom Right...../Click MultiBarBottomRightButton#
Left Bar............./Click MultiBarLeftButton#
Right Bar.........../Click MultiBarRightButton#

The pound (#) symbol will be exchanged for the button number, which in the default UI ranges from 1 to 12.

If you use a bar addon, like Bartender, Dominos or Macaroon, you will need to know the name of the button which you are clicking. Within Dominos, when you are configuring your bar (positioning, size etc) if you mouse over it will give the name of the button, which you would then use in the place of /Click MultiBarBottomLeftButton4 or whatever.



Research
We need to know our own spam speed. Open Word or Notepad. Watch a clock or your watch. Spam any letter or any number for 10 seconds. Spam at the speed you will spam during play. Count how many of the key you spammed, and divide that by 10. That is how many of the key you pressed per second. Ideally, you spam at least 2 presses per second, and as many as you can comfortably maintain. Most spam between 2 and 5 presses per second.

We also need to know information on our spells. Specifically recast delays and dot durations. We can get this information by googling: "Wow +Wiki +Class +Abilities". Substitute your class into the search.

For my destruction warlock, I came up with:
Curse of the Elements, 5 minute duration
Immolate, 15 second duration
Conflagrate, 10 second cooldown (glyphed)
Chaos Bolt, 10 second cooldown (glyphed)



Timing
Based on our spam speed, we will need to insert a number of commas into our castsequences to attain the correct timing. I personally spam at 2 clicks per second. So I need to insert 2 commas for every second of desired delay.

Immolate has a 15 second duration, so I want 30 commas in its sequence before I recast (in this case, it is a dot and I want it to run its course).

Conflagrate has a 10 second cooldown, so I want 20 commas before it attempts to recast, because it cannot be used until the cooldown expires.

I have a fall through button, which will execute if everything else is on cooldown. For my warlock this is Incinerate. It needs to be a spell which is not a dot, but can be cast as often as you desire, as soon as the GCD has expired.

Here is an web page, to help determine your spam speed: http://wow.codespin.com/



Procedure
Our master macro is typically placed on the first button of the default action bar. My warlock's master macro is:

#show Chaos Bolt
<Insert Assist Method, or Omit line if using FTL>
/Click MultiBarRightButton1
/Click MultiBarRightButton2
/Click MultiBarRightButton3
/Click MultiBarRightButton4
/Click MultiBarRightButton5

Macro on Button 1
#showtooltip Curse of the Elements
/cast [mod, nochanneling] Drain Soul
/castsequence [nochanneling] reset=target Curse of the Elements,Null

Macro on Button 2
#showtooltip Immolate
/cast [mod, nochanneling] Drain Soul
/castsequence [nochanneling] reset=target Immolate,,,,,,,,,,,,,,,,,,,,,,,,,,,,,
/use 13
/use 14
/cast [pet:imp] Firebolt

Macro on Button 3
#showtooltip Conflagrate
/cast [mod, nochanneling] Drain Soul
/castsequence [nochanneling] reset=combat Conflagrate,,,,,,,,,,,,,,,,,,,

Macro on Button 4
#showtooltip Chaos Bolt
/cast [mod, nochanneling] Drain Soul
/castsequence [nochanneling] reset=combat Chaos Bolt,,,,,,,,,,,,,,,,,,,

Macro on Button 5
#showtooltip Incinerate
/cast [mod, nochanneling] Drain Soul
/cast [nochanneling] Incinerate



Tweaking
Take your Click macro and visit a target dummy.

Drag all of the spells out of the spell book, and put them into a line, where they won't be clicked upon.

Run the click macro, and observe each spell in turn. Check to see that it is casting, and in the case of a dot that it recasts almost as soon as the dot expires. Add commas if it recasts too soon, and remove commas if there is a wait until the recast. Do the same for each other spell in your sequence.

If your haste significantly changes, it wouldn't hurt to re-tweak your Clicking.

[Ualaa]

Explanation
Everything is executed top down.

The initial click calls on each of my five macros. Anything in any of those five macros which does not incur a GCD will fire off immediately. This includes the trinket uses in the Button 2 macro and the Pet Attack action. The first thing to incur a GCD will fire off fine, but then everything else is on cooldown.

The second click again attempts to execute everything not on a GCD, and gets stuck on the next item to trigger the GCD. Because the first spell fired off fine on Button 1, that sequence advances to the first comma (which is a no action step in its sequence). The macro on Button 2 will fire off, probably on my 3rd total press (because of the GCD).

After 30 total presses of the button, the first sequence is once more at the Immolate stage, and if my spam speed was consistent, Immolate should have just expired.

Because Immolate is higher priority (occurs earlier in the sequence), Conflagrate will never attempt to fire off without Immolate having already cast. This is also true for our fall through Incinerate.

For bosses, I position the macros on the further right of the two vertical action bars. CoE on the top, Immolate under it, Conflgrate under Immolate, Chaos Bolt under Conflagrate and Incinerate under Chaos Bolt (position 5).

For trash/quests, I drag my CoE macro to position 6 (under Incinerate), which is never called by this macro, so never fires off. Why waste a GCD to debuff a mob for 5 minutes, when it will be dead in 3 seconds?



Background Information
The warcraft macro system runs top downwards. It will do everything all at once, except that if something uses the Global Cooldown (GCD), then anything else using the GCD cannot execute on that keypress.

A castsequence allows us to run multiple spells or abilities one after the other, in sequence. The problem with a castsequence is how it works. You send a request to the server, the server sends an acknowledgement. You then cast your spell. Your computer waits until the server tells it the last spell has finished before starting the next spell. You are effectively getting 2x your latency as a delay between each spell in the sequence. For low pings, this isn't much of an issue (but is still DPS lost); for high pings, a castsequence is a horrible way to deal DPS.



The Advantages of Click
1. Each portion of your DPS is in a block (macro). You can tweak a single aspect of your click sequence at once, or remove it, or reposition it in the sequence by tweaking the macro or moving it into a different position on your UI.

2. We are utlitizing multiple sequences, instead of one. There is no next spell in our sequences, so we don't need to wait on server confirmation before trying to execute the next spell. We can execute the next spell at the earliest possible moment, because we can tell client side when we are done casting and the GCD has passed.



Druid Example
Balance Druid (Insect Swarm, 12 seconds), Moonfire (12 seconds), Wrath/Starfire as a fall through.

#show Wrath
/Click MultiBarRightButton5
/Click MultiBarRightButton6
/Click MultiBarRightButton7
/use 13
/use 14

Druid 1
#show Insect Swarm
/Castsequence reset=target Insect Swarm,,,,,,,,,,,,,,,,,,,,,,,

Druid 2
#show Moonfire
/Castsequence reset=target Moonfire,,,,,,,,,,,,,,,,,,,,,,,,

Druid 3
#show Wrath
/Castrandom Wrath, Wrath, Wrath, Starfire, Starfire



Shaman Example
Elemental Shaman (Flame Shock, 18 seconds), Lava Burst (8 seconds), Chain Lightning (3.5 seconds), Lightning Bolt as a fall through.

#show Lightning Bolt
/Cast Elemental Mastery
/Click MutliBarRightButton6
/Click MultiBarRightButton7
/Click MultiBarRightButton8
/Click MultiBarRightButton9

Shaman 1
#show Flame Shock
/castsequence reset=combat Flame Shock,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,

Shaman 2
#show Lava Burst
/castsequence reset=combat Lava Burst,,,,,,,,,,,,,,,

Shaman 3
#show Chain Lightning
/castsequence reset=combat Chain Lightning,,,,,,

Shaman 4
#show Lightning Bolt
/cast Lightning Bolt

[diamond]

Awesome , thanks . Must throw a sick day from work now to get these macros in action hehe

[EaTCarbS]

excellent work! stickied

EDIT: I also thought this would fit better in the macro forums.

[Tim]

Holy crap, this is amazing!

Do you think we could have a couple screenshots included as examples of click macros and how they activate?

Amazing guide, totally going to add this to the guide section.

[Poyzon]

All 5 of my pallies are using /click macros for their main attack spam. Love this. Good job.

[ebony]

great guilde

[WhiteDragon]

why do you use this type of Castsequence?

i don't want to take the time to make one for the examples you have so ill show you mine.
HUNTER:

/castsequence reset=8 Hunter's Mark,Aimed Shot,Chimera Shot,Serpent Sting,Steady Shot,Steady Shot,Steady Shot,Aimed Shot,Chimera Shot,Steady Shot,Steady Shot,Steady Shot,Steady Shot
/petattack

it resets if i havn't pushed the button in 8 sec...it goes in order from left to right. Every push of the button progresses the castsequence to the next spell on the list till the end and then starts the sequence over from Hunter's Mark.

It will only cast the next one if it is castable.. i.e. not on CD and in range.

if you do all the math on the CD of the spell and duration of the spell you should be able to set up the spells in the correct sequence to coinside with when it isn't on CD and for when the duration runs out. and you could put the filler spells lower in the macro like how i have my /petattack
after that and below it you could put your /fillerspell <---here
and every time you pushed the button and the castsequence runs into a cd it would go down to the /fillerspell..this last part might be wrong but if you find where y run into that prob u could just put the filler spell into that part of the castsequence.

in the castsequence macro i have above the only time i run into a cd is the GCD so as soon as that is done it goes on....so another way to say this is that i never have spell not going off all the time.

doing it this way would not require you to know how many commas to use.

or am i missing somthing about y you have it set up this way?

[EaTCarbS]

These type of /click macros work more as a priority based system instead of an actual sequence... not to mention they make up for changes in haste (bloodlust/heroism).

They function almost as well as 1 person controlling the 1 toon. I was able to get 5k+ dps on the ptr with these kinds of macros

[Ualaa]

EaTCabS mentioned 2 of the 3 advantages of click sequences.

1) It is a priority system, so you can spam the same button indefinitely without the sequence ever breaking (assuming infinite mana).

2) It adjusts itself for haste, due to the fall through spell.

3) With a single castsequence, your client does not cast the next spell until the server gives confirmation that the last spell has finished. With a click sequence, every spell attempts to cast on every click, with the commas as artificial delays. The single castsequences slows your cast speed by your latency, the click sequences does not.